Update: Lotus Notes ohne Konfiguration an den Anwender übergeben

 in Lotus Notes



Die Notes NEU 8.5.bat aus dem Artikel „Lotus Notes ohne Konfiguration an den Anwender übergeben“ habe ich überarbeitet.
Das Problem war bisher, dass Anwender, die bereits den Lotus Notes Ordner auf dem persönlichen Laufwerk hatten, einfach überschrieben wurden. Das hat natürlich sehr viele Nachteile, bis hin zu einem nicht mehr funktionsfähigen Lotus Notes Client. Ist die Ordnerstruktur bereits vorhanden, wird dieser Anwender übersprungen und sofern mehrere Anwender in die txt Datei eingetragen sind mit dem nachfolgenden weiter gemacht.

Da unsere Hauptadministratoren für Notes die ID Dateien auf einem Laufwerk ablegen, prüft die neue Batch Datei natürlich auch, ob diese überhaupt vorhanden ist.

Das ganze habe ich nunmehr auch so aufbereitet, dass eine ordentliche LOG Datei geschrieben wird.

Ich wünsche viel Spaß.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
@echo off
color 9f
 
:**********************************
:Ersteller:     Boschert Patrick Ext.
:Zweck:     Anlegen eines neuen Users in Lotus Notes 8.5
:Ausführung:    manuell
:Änderungen:    -
:Version:    v 4.0 - 30.06.2015
:**********************************
 
Set Quelle=\\FilePart100\home\_Default_User_Notes\Umstellung_v8\umzustellende_User_temp_Liste.txt
SET LOG=\\FilePart100\home\_Default_User_Notes\Umstellung_v8\LN_v8_LOG.log
cls
setlocal
 
color 9f
Echo.
Echo =============================================
Echo User wird fuer Lotus Notes vorbereitet.
Echo =============================================
Echo.
for /f "tokens=1" %%i in ('type %Quelle%') do (
SET temp_Einzel-User=%%i
 
ping -n 2 127.0.0.1 > NUL
 
if not exist "\\lncluster001\e$\Notes-ID\%%i.id" call :keinenotesid
if exist "\\FilePart100\Home\%%i\Lotus\" call :ordnerschonda 
if not exist "\\FilePart100\Home\%%i\Lotus\" call :kopieren
 
)
 
cls
color 2f
Echo.
Echo =============================================
Echo Die Einrichtung fuer Lotus Notes wurde beendet.
Echo =============================================
Echo.
goto :Ende
 
:keinenotesid
cls
color cf
Echo.
Echo =============================================
Echo Keine Notes-ID gefunden.
Echo =============================================
Echo.
echo %username% - %date%, %time% ############### Keine ID Datei für %temp_Einzel-User% vorhanden. >> %LOG%
ping -n 1 127.0.0.1 > NUL
goto :eof
 
:keinenotesidII
cls
color cf
Echo.
Echo =============================================
Echo Keine Notes-ID gefunden.
Echo =============================================
Echo.
ping -n 1 127.0.0.1 > NUL
goto :eof
 
:ordnerschonda
cls
color cf
Echo.
Echo =============================================
Echo Lotus Notes bereits eingerichtet.
Echo =============================================
Echo.
echo %username% - %date%, %time% ############### Nutzer %temp_Einzel-User% ist bereits vorhanden >> %LOG%
ping -n 1 127.0.0.1 > NUL
goto :eof
 
 
:kopieren
cls
color 9f
Echo.
Echo =============================================
Echo User %temp_Einzel-User% wird fuer Lotus Notes vorbereitet.
Echo =============================================
Echo.
if not exist "\\lncluster001\e$\Notes-ID\%temp_Einzel-User%.id" goto :keinenotesidII
if not exist "\\FilePart100\home\%temp_Einzel-User%\Lotus" md "\\FilePart100\home\%temp_Einzel-User%\Lotus" 2>NUL >NUL
xcopy "\\lncluster001\e$\Notes-ID\%temp_Einzel-User%.id" "\\FilePart100\Home\%temp_Einzel-User%\Lotus\Notes\Data\"  /C /F /R /Y /V 2>NUL >NUL
xcopy "\\FilePart100\home\_Default_User_Notes\Notes\Data\*" "\\FilePart100\Home\%temp_Einzel-User%\Lotus\Notes\Data"  /Y /E /S 2>NUL >NUL
call "\\FilePart100\home\_Default_User_Notes\Umstellung_v8\Migration_NEU_PB\Batches\ini-Keyfile.cmd" 
echo %username% - %date%, %time% ############### Nutzer %temp_Einzel-User% ist vorbereitet fuer LN v8.5. >> %LOG%
goto :eof
 
:Ende
pause >nul